<xsl:template mode="scene" match="line">
  <xsl:variable name="anchor" select="@a" />

  <!-- Inline stage directions are assumed to be at the front of the line. -->
  <xsl:apply-templates mode="scene" select="sd"/>

  <xsl:if test="0 != string-length(text())">

    <a class="a-source" href="/plays/{$play-key}/{ancestor::section/@key}#{$anchor}" id="{$anchor}--n"
			 data-n="{1 + count(preceding::line[not(catch)])}"/>

    <<the line element>>
    <br/>

    <!-- Separate lines in case we're re-wrapping prose. -->
    <xsl:if test="following-sibling::line">
      <xsl:text> </xsl:text>
    </xsl:if>

  </xsl:if>
</xsl:template>

<a class="a line" href="#{$anchor}" id="{$anchor}">
  <xsl:apply-templates select="text()" />
</a>

<xsl:template name="render-line-groups" match="speech">
  <xsl:variable name="speech" select="."/>

  <xsl:for-each select="line[not(preceding-sibling::*[self::line or self::sd])] | sd">
    <xsl:variable name="pos" select="count(self::sd | preceding-sibling::sd)"/>

    <xsl:variable name="lines"
		  select="self::line
			  | following-sibling::line[count(preceding-sibling::sd) = $pos]"/>

    <xsl:variable name="full-lines" select="$lines
					    [not(catch)]
					    [not((following::line)[1][catch])]" />

    <xsl:variable name="broken-start-line" select="$lines[1][catch]"/>

    <!-- Done in speech, but may revisit for mixed speeches (e.g. songs) -->
    <!-- <xsl:variable name="is-prose" select="$speech/prose or not($lines[not(prose)])"/> -->
    <!-- <xsl:variable name="more-class"> -->
    <!--    <xsl:if test="$is-prose"> prose</xsl:if> -->
    <!-- </xsl:variable> -->


    <xsl:apply-templates mode="scene" select="self::sd" />

    <xsl:if test="$lines">
      <div class="lines">
	<xsl:apply-templates select="$broken-start-line" mode="render-broken-line" />

	<xsl:if test="$full-lines">
	  <div class="text">
	    <xsl:apply-templates select="$full-lines" mode="scene" />
	  </div>                  
	</xsl:if>

	<!-- Broken end line -->
	<xsl:apply-templates select="$lines
				     [generate-id() != generate-id($broken-start-line)]
				     [ catch or (following::line)[1][catch] ]"
			     mode="render-broken-line" />

      </div>
    </xsl:if>

  </xsl:for-each>
</xsl:template>

<!-- mode: render-broken-line -->
<xsl:template mode="render-broken-line" match="node()|@*" />

<!-- Kind of a hack: sd's get selected along with broken lines if they occur
     in a break. -->
<xsl:template mode="render-broken-line" match="sd">
  <xsl:apply-templates select="." mode="scene" />
</xsl:template>

<xsl:template mode="render-broken-line" match="line">
  <xsl:variable name="next-catch" select="(following::line)[1][catch]"/>

  <xsl:variable name="spaces" select="'                                                                                                    '"/>
  <xsl:variable name="nbsps" select="translate($spaces, ' ', ' ')"/>

  <div>
    <xsl:attribute name="class">
      <xsl:text>broken-line</xsl:text>
      <xsl:if test="following-sibling::line"> not-last</xsl:if>
      <xsl:if test="following-sibling::*[1][self::line[(following::line)[1][catch]]]"> ff</xsl:if>
    </xsl:attribute>

    <xsl:if test="catch">
      <xsl:variable name="spacer-text">
	<xsl:apply-templates select="." mode="catch-spacer-text" />
      </xsl:variable>

      <xsl:variable name="spacer-width">
	<xsl:call-template name="spacer-width">
	  <xsl:with-param name="text" select="$spacer-text"/>
	</xsl:call-template>
      </xsl:variable>

      <span class="spacer" style="width:{format-number($spacer-width div 1000, '0.##')}em">
	<xsl:value-of select="substring($nbsps, 1, string-length(normalize-space($spacer-text)))"/>
      </span>
    </xsl:if>

    <span>
      <xsl:attribute name="class">
	<xsl:text>text</xsl:text>
	<xsl:if test="catch"> catch</xsl:if>
	<!-- <xsl:if test="$next-catch"> caught</xsl:if> -->
      </xsl:attribute>

      <xsl:apply-templates mode="scene" select="." />
    </span>

    <xsl:if test="$next-catch">
      <span class="end-spacer" />
    </xsl:if>
  </div>

</xsl:template>

<xsl:variable name="widths" select="document('/static/doc/char-widths.xml')/cs" />
<xsl:key name="char-width" match="c" use="@c" />

<xsl:template name="spacer-width">
  <xsl:param name="text" />

  <xsl:variable name="c" select="substring($text, 1, 1)"/>
  <xsl:variable name="remaining-text" select="translate($text, $c, '')"/>
  <xsl:variable name="times" select="string-length($text) - string-length($remaining-text)"/>

  <xsl:variable name="width">
    <xsl:for-each select="$widths">
      <xsl:variable name="record" select="key('char-width', $c)"/>

      <xsl:choose>
	<xsl:when test="$record">
	  <xsl:value-of select="$record/@w"/>
	</xsl:when>
	<xsl:otherwise>500</xsl:otherwise>
      </xsl:choose>
    </xsl:for-each>
  </xsl:variable>

  <xsl:variable name="remaining-width">
    <xsl:text>0</xsl:text>
    <xsl:if test="$remaining-text != ''">
      <xsl:call-template name="spacer-width">
	<xsl:with-param name="text" select="$remaining-text"/>
      </xsl:call-template>
    </xsl:if>           
  </xsl:variable>

  <xsl:value-of select="$width * $times + $remaining-width"/>

</xsl:template>